Main   Changelog   Spec   Patches   Sources   Download   Gear   Bugs e FR  Repocop 

pax_global_header00006660000000000000000000000064120502442020014501gustar00rootroot0000000000000052 comment=95190a0dbcfc17e9bbdd31aec8a79898d1266369
perl-strictures-1.004004/000075500000000000000000000000001205024420200150765ustar00rootroot00000000000000perl-strictures-1.004004/.gitignore000064400000000000000000000004231205024420200170650ustar00rootroot00000000000000/META.yml
/MYMETA.*
/Makefile
/Makefile.old
/MANIFEST
/MANIFEST.bak
/blib/
/pm_to_blib
/.build
!.gitignore
*.bs
/xs/*.c
*.o
cover_db
*.gc??
test-mydeps-*
nytprof*
/inc/
!.gitignore
.*.sw?
README
Distar/
/strictures-*

# yes that's right, distar makes it for us
MANIFEST.SKIP
perl-strictures-1.004004/Changes000064400000000000000000000025061205024420200163740ustar00rootroot000000000000001.004004 - 2012-11-12
  - fix 5.16 crash due to qw() list being readonly
1.004003 - 2012-11-10
  - check only once for presence of extra testing prereqs
  - explicitly specify no dynamic_config in META
1.004002 - 2012-09-08
  - add better rationale for the extra testing heuristic
1.004001 - 2012-07-12
  - test-specific strictures now enabled during 'dzil test'
1.004000 - 2012-07-12
  - switch to testing calling file to avoid firing on dependencies
1.003001 - 2012-04-08
  - fix test to handle defatalization
1.003000 - 2012-04-07
  - try and run for any checkout t/ now we don't blow up the process
  - defatalize lack of extra testing modules
  - disable extra tests on perls <= 5.008003, things do not work there as
    expected
1.002002 - 2011-02-25
  - only try and mkdir the .git if it doesn't already exist so repeated
    test runs don't explode
1.002001 - 2011-02-25
  - switch .svn to .git in smells-of-vcs test and create it ourselves
    to ease importing of this dist into subversion repositories
1.002000 - 2011-02-16
  - add multidimensional and bareword::filehandles in author mode
1.1.1 Dec 05 2010
  - disable uninitialized warnings before calling ->SUPER::VERSION
1.1.0 Nov 22 2010
  - enable extra testing only if .git or .svn present to keep requirement
    for extra modules author-side
1.0.0 Jul 18 2010
  - initial release
perl-strictures-1.004004/Makefile.PL000064400000000000000000000011651205024420200170530ustar00rootroot00000000000000use strict;
use warnings FATAL => 'all';
use ExtUtils::MakeMaker;

(do 'maint/Makefile.PL.include' or die $@) unless -f 'META.yml';

WriteMakefile(
  NAME => 'strictures',
  VERSION_FROM => 'lib/strictures.pm',

  META_MERGE => {
    dynamic_config => 0,

    resources => {
      # r/w: p5sagit@git.shadowcat.co.uk:strictures.git
      repository => 'git://git.shadowcat.co.uk/p5sagit/strictures.git',
      homepage => 'http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=p5sagit/strictures.git',
    },

    recommends => {
        indirect => 0,
        multidimensional => 0,
        'bareword::filehandles' => 0,
    },
  },
);
perl-strictures-1.004004/lib/000075500000000000000000000000001205024420200156445ustar00rootroot00000000000000perl-strictures-1.004004/lib/strictures.pm000064400000000000000000000223321205024420200204130ustar00rootroot00000000000000package strictures;

use strict;
use warnings FATAL => 'all';

use constant _PERL_LT_5_8_4 => ($] < 5.008004) ? 1 : 0;

our $VERSION = '1.004004'; # 1.4.4

sub VERSION {
  for ($_[1]) {
    last unless defined && !ref && int != 1;
    die "Major version specified as $_ - this is strictures version 1";
  }
  # disable this since Foo->VERSION(undef) correctly returns the version
  # and that can happen either if our caller passes undef explicitly or
  # because the for above autovivified $_[1] - I could make it stop but
  # it's pointless since we don't want to blow up if the caller does
  # something valid either.
  no warnings 'uninitialized';
  shift->SUPER::VERSION(@_);
}

my $extra_load_states;

our $Smells_Like_VCS = (-e '.git' || -e '.svn'
  || (-e '../../dist.ini' && (-e '../../.git' || -e '../../.svn')));

sub import {
  strict->import;
  warnings->import(FATAL => 'all');

  my $extra_tests = do {
    if (exists $ENV{PERL_STRICTURES_EXTRA}) {
      if (_PERL_LT_5_8_4 and $ENV{PERL_STRICTURES_EXTRA}) {
        die 'PERL_STRICTURES_EXTRA checks are not available on perls older than 5.8.4: '
          . "please unset \$ENV{PERL_STRICTURES_EXTRA}\n";
      }
      $ENV{PERL_STRICTURES_EXTRA};
    } elsif (! _PERL_LT_5_8_4) {
      !!((caller)[1] =~ /^(?:t|xt|lib|blib)/
         and $Smells_Like_VCS)
    }
  };
  if ($extra_tests) {
    $extra_load_states ||= do {

      my (%rv, @failed);
      foreach my $mod (qw(indirect multidimensional bareword::filehandles)) {
        eval "require $mod; \$rv{'$mod'} = 1;" or do {
          push @failed, $mod;

          # courtesy of the 5.8 require bug
          # (we do a copy because 5.16.2 at least uses the same read-only
          # scalars for the qw() list and it doesn't seem worth a $^V check)

          (my $file = $mod) =~ s|::|/|g;
          delete $INC{"${file}.pm"};
        };
      }

      if (@failed) {
        my $failed = join ' ', @failed;
        print STDERR <<EOE;
strictures.pm extra testing active but couldn't load all modules. Missing were:

  $failed

Extra testing is auto-enabled in checkouts only, so if you're the author
of a strictures-using module you need to run:

  cpan indirect multidimensional bareword::filehandles

but these modules are not required by your users.
EOE
      }

      \%rv;
    };

    indirect->unimport(':fatal') if $extra_load_states->{indirect};
    multidimensional->unimport if $extra_load_states->{multidimensional};
    bareword::filehandles->unimport if $extra_load_states->{'bareword::filehandles'};
  }
}

1;

__END__
=head1 NAME

strictures - turn on strict and make all warnings fatal

=head1 SYNOPSIS

  use strictures 1;

is equivalent to

  use strict;
  use warnings FATAL => 'all';

except when called from a file which matches:

  (caller)[1] =~ /^(?:t|xt|lib|blib)/

and when either C<.git> or C<.svn> is present in the current directory (with
the intention of only forcing extra tests on the author side) -- or when C<.git>
or C<.svn> is present two directories up along with C<dist.ini> (which would
indicate we are in a C<dzil test> operation, via L<Dist::Zilla>) --
or when the C<PERL_STRICTURES_EXTRA> environment variable is set, in which case

  use strictures 1;

is equivalent to

  use strict;
  use warnings FATAL => 'all';
  no indirect 'fatal';
  no multidimensional;
  no bareword::filehandles;

Note that C<PERL_STRICTURES_EXTRA> may at some point add even more tests, with only a minor
version increase, but any changes to the effect of C<use strictures> in
normal mode will involve a major version bump.

If any of the extra testing modules are not present, L<strictures> will
complain loudly, once, via C<warn()>, and then shut up. But you really
should consider installing them, they're all great anti-footgun tools.

=head1 DESCRIPTION

I've been writing the equivalent of this module at the top of my code for
about a year now. I figured it was time to make it shorter.

Things like the importer in C<use Moose> don't help me because they turn
warnings on but don't make them fatal -- which from my point of view is
useless because I want an exception to tell me my code isn't warnings-clean.

Any time I see a warning from my code, that indicates a mistake.

Any time my code encounters a mistake, I want a crash -- not spew to STDERR
and then unknown (and probably undesired) subsequent behaviour.

I also want to ensure that obvious coding mistakes, like indirect object
syntax (and not so obvious mistakes that cause things to accidentally compile
as such) get caught, but not at the cost of an XS dependency and not at the
cost of blowing things up on another machine.

Therefore, L<strictures> turns on additional checking, but only when it thinks
it's running in a test file in a VCS checkout -- although if this causes
undesired behaviour this can be overridden by setting the
C<PERL_STRICTURES_EXTRA> environment variable.

If additional useful author side checks come to mind, I'll add them to the
C<PERL_STRICTURES_EXTRA> code path only -- this will result in a minor version increase (e.g.
1.000000 to 1.001000 (1.1.0) or similar). Any fixes only to the mechanism of
this code will result in a sub-version increase (e.g. 1.000000 to 1.000001
(1.0.1)).

If the behaviour of C<use strictures> in normal mode changes in any way, that
will constitute a major version increase -- and the code already checks
when its version is tested to ensure that

  use strictures 1;

will continue to only introduce the current set of strictures even if 2.0 is
installed.

=head1 METHODS

=head2 import

This method does the setup work described above in L</DESCRIPTION>

=head2 VERSION

This method traps the C<< strictures->VERSION(1) >> call produced by a use line
with a version number on it and does the version check.

=head1 EXTRA TESTING RATIONALE

Every so often, somebody complains that they're deploying via C<git pull>
and that they don't want L<strictures> to enable itself in this case -- and that
setting C<PERL_STRICTURES_EXTRA> to 0 isn't acceptable (additional ways to
disable extra testing would be welcome but the discussion never seems to get
that far).

In order to allow us to skip a couple of stages and get straight to a
productive conversation, here's my current rationale for turning the
extra testing on via a heuristic:

The extra testing is all stuff that only ever blows up at compile time;
this is intentional. So the oft-raised concern that it's different code being
tested is only sort of the case -- none of the modules involved affect the
final optree to my knowledge, so the author gets some additional compile
time crashes which he/she then fixes, and the rest of the testing is
completely valid for all environments.

The point of the extra testing -- especially C<no indirect> -- is to catch
mistakes that newbie users won't even realise are mistakes without
help. For example,

  foo { ... };

where foo is an & prototyped sub that you forgot to import -- this is
pernicious to track down since all I<seems> fine until it gets called
and you get a crash. Worse still, you can fail to have imported it due
to a circular require, at which point you have a load order dependent
bug which I've seen before now I<only> show up in production due to tiny
differences between the production and the development environment. I wrote
L<http://shadow.cat/blog/matt-s-trout/indirect-but-still-fatal/> to explain
this particular problem before L<strictures> itself existed.

As such, in my experience so far L<strictures>' extra testing has
I<avoided> production versus development differences, not caused them.

Additionally, L<strictures>' policy is very much "try and provide as much
protection as possible for newbies -- who won't think about whether there's
an option to turn on or not" -- so having only the environment variable
is not sufficient to achieve that (I get to explain that you need to add
C<use strict> at least once a week on freenode #perl -- newbies sometimes
completely skip steps because they don't understand that that step
is important).

I make no claims that the heuristic is perfect -- it's already been evolved
significantly over time, especially for 1.004 where we changed things to
ensure it only fires on files in your checkout (rather than L<strictures>-using
modules you happened to have installed, which was just silly). However, I
hope the above clarifies why a heuristic approach is not only necessary but
desirable from a point of view of providing new users with as much safety as possible,
and will allow any future discussion on the subject to focus on "how do we
minimise annoyance to people deploying from checkouts intentionally".

=head1 COMMUNITY AND SUPPORT

=head2 IRC channel

irc.perl.org #toolchain

(or bug 'mst' in query on there or freenode)

=head2 Git repository

Gitweb is on http://git.shadowcat.co.uk/ and the clone URL is:

  git clone git://git.shadowcat.co.uk/p5sagit/strictures.git

The web interface to the repository is at:

  http://git.shadowcat.co.uk/gitweb/gitweb.cgi?p=p5sagit/strictures.git

=head1 AUTHOR

mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>

=head1 CONTRIBUTORS

None required yet. Maybe this module is perfect (hahahahaha ...).

=head1 COPYRIGHT

Copyright (c) 2010 the strictures L</AUTHOR> and L</CONTRIBUTORS>
as listed above.

=head1 LICENSE

This library is free software and may be distributed under the same terms
as perl itself.

=cut
perl-strictures-1.004004/maint/000075500000000000000000000000001205024420200162065ustar00rootroot00000000000000perl-strictures-1.004004/maint/Makefile.PL.include000064400000000000000000000003651205024420200216060ustar00rootroot00000000000000BEGIN { -e 'Distar' or system("git clone git://git.shadowcat.co.uk/p5sagit/Distar.git") }
use lib 'Distar/lib';
use Distar;

author 'mst - Matt S. Trout (cpan:MSTROUT) <mst@shadowcat.co.uk>';

manifest_include(
  't/smells-of-vcs' => qr{.*},
);
perl-strictures-1.004004/maint/Makefile.include000064400000000000000000000002751205024420200212740ustar00rootroot00000000000000bump:
	maint/bump-version
	rm Makefile
bumpminor:
	maint/bump-version minor
	rm Makefile
bumpmajor:
	maint/bump-version major
	rm Makefile
upload: $(DISTVNAME).tar$(SUFFIX)
	cpan-upload $<
perl-strictures-1.004004/maint/bump-version000075500000000000000000000014421205024420200205630ustar00rootroot00000000000000#!/usr/bin/env perl

use 5.010;
use strict;
use warnings FATAL => 'all';
use autodie;

chomp(my $LATEST = qx(grep '^[0-9]' Changes | head -1 | awk '{print \$1}'));

my @parts = split /\./, $LATEST;

my $OLD_DECIMAL = sprintf('%i.%03i%03i', @parts);

my %bump_part = (major => 0, minor => 1, bugfix => 2);

my $bump_this = 
  $bump_part{$ARGV[0]||'bugfix'}
    // die "no idea which part to bump - $ARGV[0] means nothing to me";

my @new_parts = @parts;

$new_parts[$bump_this]++;

my $NEW_DECIMAL = sprintf('%i.%03i%03i', @new_parts);

warn "Bumping $OLD_DECIMAL -> $NEW_DECIMAL\n";

my $PM_FILE = 'lib/Module/Metadata.pm';

my $file = do { local (@ARGV, $/) = ($PM_FILE); <> };

$file =~ s/(?<=\$VERSION = ')${\quotemeta $OLD_DECIMAL}/${NEW_DECIMAL}/;

open my $out, '>', $PM_FILE;

print $out $file;
perl-strictures-1.004004/t/000075500000000000000000000000001205024420200153415ustar00rootroot00000000000000perl-strictures-1.004004/t/crash.t000064400000000000000000000004541205024420200166310ustar00rootroot00000000000000use strictures;

use Test::More tests => 1;

SKIP: {
  skip 'Have all the modules; can\'t check this', 1
    unless not eval {
      require indirect;
      require multidimensional;
      require bareword::filehandles;
      1;
    };

  pass('can manage to survive with some modules missing!');
}

perl-strictures-1.004004/t/smells-of-vcs/000075500000000000000000000000001205024420200200335ustar00rootroot00000000000000perl-strictures-1.004004/t/smells-of-vcs/.exists000064400000000000000000000000001205024420200213410ustar00rootroot00000000000000perl-strictures-1.004004/t/smells-of-vcs/lib/000075500000000000000000000000001205024420200206015ustar00rootroot00000000000000perl-strictures-1.004004/t/smells-of-vcs/lib/one.pm000064400000000000000000000000621205024420200217160ustar00rootroot00000000000000package one;

use strictures 1;

new Foo 1, 2, 3;
perl-strictures-1.004004/t/smells-of-vcs/other/000075500000000000000000000000001205024420200211545ustar00rootroot00000000000000perl-strictures-1.004004/t/smells-of-vcs/other/one.pl000064400000000000000000000000441205024420200222700ustar00rootroot00000000000000use strictures 1;

new Foo 1, 2, 3;
perl-strictures-1.004004/t/smells-of-vcs/t/000075500000000000000000000000001205024420200202765ustar00rootroot00000000000000perl-strictures-1.004004/t/smells-of-vcs/t/one.faket000064400000000000000000000000441205024420200220710ustar00rootroot00000000000000use strictures 1;

new Foo 1, 2, 3;
perl-strictures-1.004004/t/strictures.t000064400000000000000000000027561205024420200177470ustar00rootroot00000000000000BEGIN { delete $ENV{PERL_STRICTURES_EXTRA} }

# -e is sufficient here.
-e 't/smells-of-vcs/.git'
  or mkdir('t/smells-of-vcs/.git')
  or die "Couldn't create fake .git: $!";

use Test::More qw(no_plan);

our (@us, @expect);

sub capture_stuff { [ $^H, ${^WARNING_BITS} ] }

sub capture_us { push @us, capture_stuff }
sub capture_expect { push @expect, capture_stuff }

{
  BEGIN { $ENV{PERL_STRICTURES_EXTRA} = 0 }
  use strictures 1;
  BEGIN { capture_us }
  BEGIN { delete $ENV{PERL_STRICTURES_EXTRA} }
}

{
  use strict;
  use warnings FATAL => 'all';
  BEGIN { capture_expect }
}

# I'm assuming here we'll have more cases later. maybe not. eh.

foreach my $idx (0 .. $#us) {
  is($us[$idx][0], $expect[$idx][0], 'Hints ok for case '.($idx+1));
  is($us[$idx][1], $expect[$idx][1], 'Warnings ok for case '.($idx+1));
}

SKIP: {
  skip 'Extra tests disabled on perls <= 5.008003', 1
    if $] < 5.008004;
  skip 'Not got all the modules to do this', 1
    unless eval {
      require indirect;
      require multidimensional;
      require bareword::filehandles;
      1;
    };
  sub Foo::new { 1 }
  chdir("t/smells-of-vcs");
  local $strictures::Smells_Like_VCS = 1;
  foreach my $file (qw(lib/one.pm t/one.faket)) {
    ok(!eval { require $file; 1 }, "Failed to load ${file}");
    like($@, qr{Indirect call of method}, "Failed due to indirect.pm, ok");
  }
  ok(eval { require "other/one.pl"; 1 }, "Loaded other/one.pl ok");
}

ok(!eval q{use strictures 2; 1; }, "Can't use strictures 2 (this is version 1)");
perl-strictures-1.004004/xt/000075500000000000000000000000001205024420200155315ustar00rootroot00000000000000perl-strictures-1.004004/xt/pod.t000064400000000000000000000005441205024420200165030ustar00rootroot00000000000000use Test::More;
use Test::Pod;
use Test::Pod::Coverage;
use strict;
use warnings FATAL => 'all';

# the all_ things attempt to plan, which we didn't want, so stop them
# from doing that
no warnings 'redefine';
local *Test::Builder::plan = sub { };

all_pod_files_ok;
all_pod_coverage_ok({ coverage_class => 'Pod::Coverage::CountParents' });

done_testing;